Завантаження...

Lump of granite - geograph.org.uk - 213679
 

 

 

This photo was viewed 0 times and was downloaded in full size 0 times.

This photo was liked 0 times

Please login in order to see the source link

Summary

Cut-away rendering of siphon lock, with number annotations and an indication of the pressure depth of the water inside the lock.

Description 3D computer graphics showhing a cut-away overview of siphon lock
Date 4 December 2006(2006-12-04)
Source Own work
Author Søren Peo Pedersen
Permission
(Reusing this file)

GFDL-self

Licensing

I, the copyright holder of this work, hereby publish it under the following licenses:
GNU head Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.

w:en:Creative Commons
attribution share alike
This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
You are free:
  • to share – to copy, distribute and transmit the work
  • to remix – to adapt the work
Under the following conditions:
  • attribution – You must attribute the work in the manner specified by the author or licensor (but not in any way that suggests that they endorse you or your use of the work).
  • share alike – If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one.
This licensing tag was added to this file as part of the GFDL licensing update.

You may select the license of your choice.

POV-Ray code

This image was rendered using the Persistence of Vision Raytracer (or POV-Ray for short), using the scene description code shown below. To render, POV-Ray needs access to the "Timesbd.ttf" TrueType font file, which is used for the number annotations.

/*
===============================================
Annotated cut-away rendering of the siphon lock
-----------------------------------------------
Created by Søren Peo Pedersen - see my user pa-
ge at http://da.wikipedia.org/wiki/Bruger:Peo
===============================================
*/

#declare txtRedCutFace=texture {  // Texture for cutaway surfaces on pipework:
  pigment {color rgb <1,0,0>} // <== Edit this line to change color
  finish {ambient .4}
  }

#declare txtPipeMetal=texture { // Metal testure used for the pipework
  pigment {color rgb .4}
  finish {ambient .4 reflection .4 metallic 1 phong 1}
  }

#declare CleanWater=material {        // Texture for (relatively)
  texture {                           // clean water inside the
    pigment {color rgbf <.8,.9,1,1>}  // siphon lock
    finish {ambient .4 reflection .1}
    }
  interior {ior 1.3}
  }
  
#declare FilthyWater=material {       // Texture for filthy water
  texture {                           // in the large sewage pipe
    pigment {
      granite                           // Lumpy appearance...!
      color_map {
        [0 color rgbf <.6,.73,.75,1>]   // Has a more "sick" color
        [.3 color rgbf <.6,.73,.75,1>]  // and spots or "lumps"
        [1 color rgbf <.6,.5,.3,.6>]    // with brownish color!    
        }
      scale <10,3,3>
      }
    finish {ambient .4 reflection .1}
    }
  interior {ior 1.3}
  }

#declare SemicircPipe=difference {  // Semicircular
  torus {2,1}                       // piece of pipe
  torus {2,.9}
  plane {<0,0,-1>,0}
  rotate <-90,0,0>
  }

#declare SemicircWater=difference { // Shape of the water
  torus {2,.901}                    // volume inside above-
  plane {<0,0,-1>,-.001}            // mentioned pipe.
  rotate <-90,0,0>
  }

difference {  // Cut-away of plumbing:
  merge { // Plumbing:
    // The "sink" symbolizing the source of waste water:
    /* Hole at bottom */ difference {torus {1.3,.4 translate <-4,4,0>} torus {1.3,.3 translate <-4,3.8,0>} cylinder {<-4,3.8,0>,<-4,6,0>,1.3 inverse}}
    /* Bowl-shape */     difference {torus {1.3,2 translate <-4,6.1,0>} torus {1.3,1.7 translate <-4,6.1,0>} cylinder {<-4,0,0>,<-4,8,0>,1.3} plane {<0,-1,0>,-6.1}}
    /* Bowl-shape */     difference {torus {3.4,.4 translate <-4,6.1,0>} torus {3.4,.1 translate <-4,6.1,0>} cylinder {<-4,6.1,0>,<-4,8,0>,3.4 inverse}}
    /* "Tabletop" */     difference {box {<-7.6,6.2,-1>,<-.4,6.5,3.6>} cylinder {<-4,6,0>,<-4,7,0>,3.4}}
    
    // Straight piece of pipe betw. sink and trap:
    difference {cylinder {<-4,2,0>,<-4,4,0>,1} cylinder {<-4,1,0>,<-4,5,0>,.9}}
    
    // The siphon trap:
    #object {SemicircPipe translate <-2 ,2,0>}
    #object {SemicircPipe rotate <0,0,180> translate <2,2,0>}
    
    // Large sewer pipe with connection to siphon trap:
    difference {
      merge {
        blob {threshold 0.5 cylinder {<2,10,0>,<2,-3,0>,.7,2.084} cylinder {<-100,-3,0>,<100,-3,0>,2,3}}
        cylinder {<-.3,-3,0>,<.3,-3,0>,1.7 translate <-3,0,0>}  // "Joints"
        cylinder {<-.3,-3,0>,<.3,-3,0>,1.7 translate <1,0,0>}   // between
        cylinder {<-.3,-3,0>,<.3,-3,0>,1.7 translate <3,0,0>}   // "sections"
        cylinder {<2,-1,0>,<2,-.8,0>,.6}                        // of pipe
        }
      blob {threshold 0.8 cylinder {<2,10,0>,<2,-3,0>,.7,2.324} cylinder {<-100,-3,0>,<100,-3,0>,2,3}}
      plane {<0,-1,0>,-1}
      scale 2
      }
    } // (end of merge containing all the pipework)
  
  plane {<0,0,1>,0}  // Cuts away one half to see inside
  texture {planar texture_map {
      [0.000 txtPipeMetal]
      [0.999 txtPipeMetal]
      [0.999 txtRedCutFace]
      [1.000 txtRedCutFace]
      } rotate <90,0,0>}}
  
  // Clean water inside lock:
  intersection {
    merge {
      #object {SemicircWater translate <-2 ,2,0>}
      #object {SemicircWater rotate <0,0,180> translate <2,2,0>}
      cylinder {<-4,2,0>,<-4,4,0>,.9001}
      }
    box {<-9,-9,0>,<2,3.1,5>}
    material {CleanWater}
    }

  // Dark greenish/brown "fumes" to symbolize foul smell from sewer
  difference {  // Shape of the volume of (smelly) air trapped behind the lock
    merge {
      difference {
        blob {threshold 0.8 cylinder {<2,10,0>,<2,-3,0>,.7,2.324} cylinder {<-100,-3,0>,<100,-3,0>,2,3} scale 2}
        plane {<0,-1,0>,-2}
        }
      #object {SemicircWater rotate <0,0,180> translate <2,2,0>}
      }
    plane {<0,0,1>,0}
    plane {<0,1,0>,-5.999}
    box {<-9,0,-5>,<2,3.1001,5>}
    pigment {color rgbt 1}
    hollow
    interior {
      media {
        intervals 10 samples 1,1 confidence 0.9 variance 1/128 ratio 0.9
        absorption rgb<.38,.33,.6>  method 1 density {granite scale 10}
        }
      }
    }
  
  // "Bad" water in sewer pipe:
  intersection {
    cylinder {<-100,-6,0>,<100,-6,0>,2.351226}
    box {<-100,-20,-.4>,<100,-7,5>}
    material {FilthyWater}
    }

union {   // Line and arrow indicating the "depth" of the lock
  #local Cnt=0;     // Loop to make dot-dashed line
  #while (Cnt<16)
    box {<-5.3+Cnt*.5,3.08,-.0001>,<-5+Cnt*.5,3.12,0>}
    #local Cnt=Cnt+1;    
  #end
  triangle {<-2,3.1,0>,<-2.2,2.6,0>,<-1.8,2.6,0>}
  triangle {<-2,0.9,0>,<-2.2,1.4,0>,<-1.8,1.4,0>}
  box {<-2.05,1.4,-.00001>,<-1.95,2.6,0>}
  pigment {color rgb 0} no_shadow no_reflection
  }

union { // Number annotations
  text {ttf "timesbd.ttf","1",.001,0 translate <-1.8,2.2,0>}  // 1: Drain from sink, WC, etc.
  text {ttf "timesbd.ttf","2",.001,0 translate <2.5,.5,0>}    // 2: Water level on sewer side
  text {ttf "timesbd.ttf","3",.001,0 translate <-1.8,.3,0>}   // 3: Water level on drain side
  text {ttf "timesbd.ttf","4",.001,0 translate <3.3,-2,0>}    // 4: Connection to sewer
  text {ttf "timesbd.ttf","5",.001,0 translate <0,-1.6,0>}  // 5: Water inside siphon lock  
  scale .00001
  translate <0,0,-13.88692>
  pigment {color rgb 0}
  rotate <13.74679514,15.47863817,0>
  translate <-2.4,1.7,0>
  }
  
camera {
  location <-6,5,-13>
  look_at <-2.4,1.7,0>
  angle 55
  }

#declare Spotty=pigment { // Pattern for "spotty
   bumps                   // surroundings", to
   color_map {             // make metal look
     [0 color rgb 0]       // "really metallic".
     [1 color rgb 1]
     }
   scale .3
   }
  
sky_sphere {pigment { // Combine spotty pattern
  gradient z          // with a neutral, white
  pigment_map {       // background for the a-
    [0 Spotty]        // rea the camera "sees".
    [.9 Spotty]
    [.8 color rgb 1]
    [1 color rgb 1]
    }
  translate -.5
  scale 2
  rotate <19,15.4,0>
  }}
 
light_source {<-100,70,-230> color rgb 1}


Licensing:
GNU Free Documentation License

Comments

Only registered users can post comments. Please login



EXIF data:
File name lump_of_granite_-_geograph.org.uk_-_213679.jpg
Size, bytes 101732
Mime type image/jpeg
The images at Free-Photos.biz come mainly from Wikimedia Commons or from our own production. The photos are either in the public domain, or licensed under free linceses: Free-Photos.biz license, GPL, Creative Commons or Free-Art license. Some very few other photos where uploaded to Free-Photos.biz by our users and released into the public domain or into free usage under another free license (like GPL etc.)

All photos in average size can be saved by everyone without registration (by right-clicking) - and all photos can be downloaded in full-size and without the big watermark by members (by left-clicking) (registration and free membership required).

While the copyright and licensing information supplied for each photo is believed to be accurate, Free-Photos.biz does not provide any warranty regarding the copyright status or correctness of licensing terms. If you decide to reuse the images from Free-Photos.biz, you should verify the copyright status of each image just as you would when obtaining images from other sources.


The use of depictions of living or deceased persons may be restricted in some jurisdictions by laws regarding personality rights. Such images are exhibited at Free-Photos.biz as works of art that serve higher artistic interests.

christianity portal